Univerzální formuláře - Příklad 105 - Spuštění formuláře s výběrem

type
  TCommandShowDataMExecuteFunction = procedure(ADataM: TDataM; AInstance: TObject = Nil; AParameters: VariantOpenArray = Nil);

class procedure TPemaCommand.CommandShowDataM(             // Zobrazeni datoveho modulu a zavolani funkce pro oznacene zaznamy po jeho zavreni
  ADataMNo: Integer;                                       // Cislo datoveho modulu
  AIndex: Integer;                                         // Index datoveho modulu
  APrimaryKeyRID: Int64 = 0;                               // Nastaveni primarniho klice
  AFunction: TCommandShowDataMExecuteFunction = Nil;       // Volana funkce
  AInstance: TObject = Nil;                                // Instance predavana volane funkci
  AParameters: VariantOpenArray = Nil;                     // Parametry predavane volane funkci, napr. datovy modul, do ktereho se ulozi oznacene zaznamy
  AShowCommands: Boolean = True;                           // Zobrazovat vychozi commandy (tlacitka)
  AViewMode: TUFViewMode = vwmLookup;                      // Mod zobrazeni
  ATypeId: Integer = 0;                                    // Typ pro zobrazeni DM ciselniku
  ACaption: String = '');                                  // Nazev zobrazeneho modulu, pokud ma byt odlisny od vychoziho, napr. pro ciselniky
{$IFNDEF SCRIPTEX}
var
  LVE: TViewExecutor;
  LDataM: TDataM;
  LField: TDataField;
begin
  LVE := TUniFormManager.CreateViewExecutor;
  LDataM := CreateDMByDataMNo(ADataMNo, True);
  try
    LDataM.SetState(tfNormal, AIndex, False);
    if APrimaryKeyRID <> 0 then begin
      LDataM.DoGetKeyBySingleSegmentPK(APrimaryKeyRID);
    end;
    if ATypeId > 0 then begin
      LField := LDataM.FieldByProgName('TypeId');
      if Assigned(LField) then begin
        LField.AsLong := ATypeId;
        LDataM.SetDataType;
      end;
    end;
    LVE.Instance := LDataM;
    LVE.ViewMode := AViewMode;
    if ACaption <> '' then begin
      LVE.Caption := ACaption;
    end;
    if AShowCommands then begin
      LVE.DialogCommands := [cmdOKView, cmdCancelView];
    end;
    if (LVE.ShowInModalForm(True) In [ufvrYes, ufvrOK]) And Assigned(AFunction) then begin
      if (LDataM.SelectionCount > 0) And (LDataM Is TBaseDataM) then begin
        if (LDataM As TBaseDataM).SetFirstSelected then begin
          while (LDataM As TBaseDataM).DoNextSelected do begin
            AFunction(LDataM, AInstance, AParameters);     // Provedeni funkce pro oznacene zaznamy
          end;
        end;
      end else
      if (LDataM.FilterType = tfFiltr) Or (LDataM.FilterType = tfMemorySet) then begin
        LDataM.SetFirst;
        while LDataM.DoNext do begin
          AFunction(LDataM, AInstance, AParameters);       // Provedeni funkce pro filtr nebo kontejner
        end;
      end else begin
        AFunction(LDataM, AInstance, AParameters);         // Provedeni funkce pro jeden (aktualni) zaznam
      end;
    end;
  finally
    LDataM.Free;
    LVE.Free;
  end;
{$ELSE}
begin
{$ENDIF}
end;